And now for hunters! I hear a lot of people complain about the lack of bar space, especially for this class, so I tend to stick modifier macros where ever possible (and whenever the abilities "fit" together)!

If you don't know what a modifier macro is, here's a basic one.

#showtooltip
/cast [modifier:alt] Disengage; Wing Clip

This one will cast Wing Clip as its default, but, if I hold Alt, I can then cast Disengage! Neat, huh?

I also use modifier macros (using that exact layout) for Distracting Shot/Kill Shot, Flare/Volley, and Aspect of the Pack/Aspect of the Cheetah. :3 (You can do the same thing with traps, too... But I like seeing all my trap buttons, haha.)

And so, onto other hunter-y macros!

Starting with the ranged abilities!

#showtooltip Hunter's Mark
/cast [harm] Hunter's Mark;
/focus [help]

Casts Hunter's Mark when an enemy is targeted. If you have an ally targeted, this macro will make him/her your focus target. Why did I do that? Well, it's for the next macro...

#showtooltip Misdirection
/cast [target=focus] Misdirection

I'm too lazy to change the "target=" to the tank's name every time I get into a group. So, I just make the tank my focus target. Problem solved! 8D

#showtooltip Steady Shot
/console Sound_EnableSFX 0
/cast !Auto Shot
/cast Steady Shot
/console Sound_EnableSFX 1
/script UIErrorsFrame:Clear()

The "Steady Shot Spam" macro. Doesn't have that *click!* sound when you mash the button and removes the error frame (the red text that pops up).

#showtooltip
/cast [modifier:alt] Viper Sting; [modifier:ctrl] Scorpid Sting; Serpent Sting

All of my Stings in one button! Default shows Serpent, holding Alt casts Viper, and holding Control casts Scorpid.

...And now for pet macros!

#showtooltip
/cast [modifier:alt] Revive Pet; [nopet] Call Pet; [pet] Dismiss Pet

The "Call Pet" macro. If your pet is already out, Dismiss Pet will show up instead. Holding Alt casts Revive Pet.

#showtooltip Feed Pet
/cast [nocombat] Feed Pet
/use [nocombat] Smoked Talbuk Venison

The "Feed Pet" macro. Just replace the second line with whatever food you want.

/cast Bestial Wrath
/cast Rapid Fire
/cast Kill Command
/use 13
/use 14
/cast Blood Fury

The "I WIN!" button. XD Casts Bestial Wrath, Rapid Fire, Kill Command, both of your trinkets and (Orc only) Blood Fury in one global cooldown.